【Arduino】ESP32でHTTP（POST）を試してみる

前記事のGETに続いてPOSTでも値を渡してみます。

GETでURLの末尾にふくめていたパラメータをリクエストに含める形になります。

開発環境

• Mac Book （12.1）
• Arduino IDE （1.8.19）

テストコード

WiFiClientにPOSTを指定し、Content-Typeを追加します。

// リクエスト(POST).
client.print("POST " + path + " HTTP/1.1\r\n" +
       "Host: " + host + "\r\n" + 
       "Content-Type:application/x-www-form-urlencoded\r\n" + 
       "Content-Length:" + String(body.length()) + "\r\n" + 
       "Connection: close\r\n\r\n" +
       body);

全文は以下になります。

#include <WiFi.h>

const int httpPort = 80;

// 各自環境に合わせて設定.
const char* ssid = "XXXXXXXXXXXXXXXXXX";
const char* password = "XXXXXXXXXX";

const char* host = "XXXX.YYYY.ZZZZ.jp";
String path = "/api.php";  
String body = "id=1";

void setup()
{
    Serial.begin(115200);

    Serial.print("Connecting to ");
    Serial.println(ssid);

    // 接続先設定.
    WiFi.begin(ssid, password);

    // 接続完了まで待機.
    while (WiFi.status() != WL_CONNECTED)
    {
        delay(500);
        Serial.print(".");
    }

    // 接続完了.
    Serial.println("WiFi connected");
    Serial.println("IP address: ");
    Serial.println(WiFi.localIP());
}

void loop()
{
    delay(5000);

    Serial.print("connecting to ");
    Serial.println(host);

    // 接続.
    WiFiClient client;
    if (!client.connect(host, httpPort))
    {
        Serial.println("connection failed");
        return;
    }

    // リクエスト(POST).
    client.print("POST " + path + " HTTP/1.1\r\n" +
       "Host: " + host + "\r\n" + 
       "Content-Type:application/x-www-form-urlencoded\r\n" + 
       "Content-Length:" + String(body.length()) + "\r\n" + 
       "Connection: close\r\n\r\n" +
       body);

    // 一定時間レスポンスがなければタイムアウト.
    unsigned long timeout = millis();
    while (client.available() == 0)
    {
        if (millis() - timeout > 5000)
        {
            Serial.println(">>> Client Timeout !");
            client.stop();
            return;
        }
    }

    // レスポンスを１行ごとに表示.
    while(client.available())
    {
        String line = client.readStringUntil('\r');
        Serial.print(line);
    }

    Serial.println();
    Serial.println("closing connection");
}